ESP32の使い方 〜「HTTPClient」でGETリクエストする

私はこれまで、ESP32からWebサーバにGETリクエストする際には「WiFiClient」を使っていましたが、とある用途でArduinoスケッチについて調査していたところ、同様の処理を行うことができる「HTTPClient」というものを見つけました。

そのため今回、「HTTPClient」について動作確認してみました。
ESP32で「10秒毎に乱数の値を取得し、その値をWi-Fi経由でWebサーバにGET送信」してみることとします。



まずはこれまで使ってきた「WiFiClient」を利用するスケッチです。「スケッチ例」＞「WiFi」＞「WiFiClient」を若干修正しただけです。

#include <WiFi.h>

const char* ssid = "XXXXXXXX";
const char* pass = "XXXXXXXX";
const char* host = "XXXXXXXX";
const char* path = "/XXXXXXXX/XXXXXXXX.php";

void setup() {
  Serial.begin(115200);
  Serial.println();

  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, pass);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");
}

void loop() {
  float val0 = random(0, 1000) / 10.0;

  Serial.print("Connecting to ");
  Serial.println(host);
  WiFiClient client;

  String url = String(path) + "?val0=" + val0;
  Serial.print("Requesting URL: ");
  Serial.println(url);

  const int httpPort = 80;
  if (!client.connect(host, httpPort)) {
    Serial.println("Connection failed");
    return;
  }

  String sendData = "GET " + url + " HTTP/1.1\r\n"
                  + "Host: " + host + "\r\n"
                  + "Connection: close\r\n\r\n";
  client.print(sendData);

  unsigned long timeout = millis();
  while (client.available() == 0) {
    if (millis() - timeout > 5000) {
      Serial.println("Client Timeout!");
      client.stop();
      return;
    }
  }
  while (client.available()) {
    String line = client.readStringUntil('\r');
    Serial.print(line);
  }
  Serial.println();
  Serial.println("closing connection");

  delay(10000);
}

送信先がSSL化されている場合は以下のようになります。「スケッチ例」＞「WiFiClientSecure」＞「WiFiClientInsecure」を参考にして、先ほどのスケッチを修正しました。

#include <WiFiClientSecure.h>

const char* ssid = "XXXXXXXX";
const char* pass = "XXXXXXXX";
const char* host = "XXXXXXXX";
const char* path = "/XXXXXXXX/XXXXXXXX.php";

void setup() {
  Serial.begin(115200);
  Serial.println();

  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, pass);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");
}

void loop() {
  float val0 = random(0, 1000) / 10.0;

  Serial.print("Connecting to ");
  Serial.println(host);
  WiFiClientSecure client;

  String url = String(path) + "?val0=" + val0;
  Serial.print("Requesting URL: ");
  Serial.println(url);

  const int httpPort = 443;
  client.setInsecure();
  if (!client.connect(host, httpPort)) {
    Serial.println("Connection failed");
    return;
  }

  String sendData = "GET " + url + " HTTP/1.1\r\n"
                  + "Host: " + host + "\r\n"
                  + "Connection: close\r\n\r\n";
  client.print(sendData);

  unsigned long timeout = millis();
  while (client.available() == 0) {
    if (millis() - timeout > 5000) {
      Serial.println("Client Timeout!");
      client.stop();
      return;
    }
  }
  while (client.available()) {
    String line = client.readStringUntil('\r');
    Serial.print(line);
  }
  Serial.println();
  Serial.println("closing connection");

  delay(10000);
}

次に、同様の処理を「HTTPClient」で実行してみます。「スケッチ例」＞「HTTPClient」＞「BasicHttpClient」を元にして、先ほどのスケッチと体裁を揃えました。

#include <WiFi.h>
#include <HTTPClient.h>

const char* ssid = "XXXXXXXX";
const char* pass = "XXXXXXXX";
const char* host = "XXXXXXXX";
const char* path = "/XXXXXXXX/XXXXXXXX.php";

void setup() {
  Serial.begin(115200);
  Serial.println();

  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, pass);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");
}

void loop() {
  float val0 = random(0, 1000) / 10.0;

  Serial.print("Connecting to ");
  Serial.println(host);
  HTTPClient http;

  String url = String("https://") + host + path + "?val0=" + val0;
  Serial.print("Requesting URL: ");
  Serial.println(url);

  Serial.println("[HTTP] begin...");
  http.begin(url);
  Serial.println("[HTTP] GET...");
  int httpCode = http.GET();

  if(httpCode > 0) {
    Serial.printf("[HTTP] GET... code: %d\n", httpCode);
    if(httpCode == HTTP_CODE_OK) {
      String line = http.getString();
      Serial.println(line);
    } 
  } else {
    Serial.printf("[HTTP] GET... failed, error: %s\n", http.errorToString(httpCode).c_str());
  }
  http.end();

  delay(10000);
}

いずれでも、問題なくWebサーバにデータ送信することができました。
また「HTTPClient」では、SSL化されているサイトにデータ送信する場合でも、送信先（url）を変更するだけで問題なく処理できました。

「WiFiClient」と「HTTPClient」のスケッチを比較すると分かるとおり、「HTTPClient」はGETリクエストの処理部分がスッキリしています。
Basic認証されているサイトにデータ送信する場合も「http.begin(url);」の後に以下を追記するだけでよく、とても簡単です。

http.setAuthorization("user", "password");

「HTTPClient」を使うことで、スケッチを従来のものよりもシンプルにすることができそうです。


By msr | 2024年3月25日 | IoT |